(Originally published in Feb 2024; updated in Aug 2025)

When you enter a ColdFusion serial number, whether during installation or via the CF Admin “Licensing and Activation” page, the activation of that license (new since CF2021) should take place immediately, interacting with the Adobe licensing server over the internet.

And when the server is offline/on a private network or CF is not connected to the internet (such as via proxy settings in the CF Admin Package Manager>Settings page), the CF Admin activation page should lead you through a process to perform “offline activation”. This is discussed in another post here. 

But if that somehow doesn’t work or especially if you do not have access to ColdFusion Administrator (but you do know its password), you may find it beneficial to perform the  activation process using CFML code that calls upon the CF Admin API (a set of CFC’s provided with ColdFusion to perform admin functionality via code). 

In CF2023, the following code will allow you to perform offline activation via the Admin API. (Note that the specific Admin API methods in the license.cfc which are used for activation are available only in CF2023, not CF2021 nor CF2025.)

1) First, create a file (such as generate_request_file.cfm, which you can save under cfusion\wwwroot directory), using the following code:

<cfscript>
   adminObj = createObject("component","cfide.adminapi.administrator")
   adminObj.login("password"); //CF admin password

   // Define previousSN with your CF2021 serial number, if your CF2023 was bought as an "upgrade" license
   //previousSN="previous serial number"
   currentSN="xxxx-xxxx-xxxx-xxxx-xxxx-xxxx" ; // dashes must be included in the serial numbers

   // instantiate the license object
   myObj = createObject("component","CFIDE.adminapi.license")

   // generate offline activation request
   try{
      // if a previousSN is defined, pass that as a second argument to the method
      myObj.generateOfflineActivationRequest(currentSN)
   }
   catch(any e){
      writeDump(var=e.message,abort=true)
   }
   writeoutput("Finished. You should now find a {uuid}-request.json file created in CF's cfusion\bin\.config folder.")
</cfscript>

The “password” value above is the CF admin credentials for login. Note that any serial numbers used must include the hyphens. If you purchased an upgrade license from CF2021 to 2023, see the two comments above about handling that using the previousSN variable.

2) Execute this template. If you created it in CF’s cfusion/wwwroot folder, you should be able to execute it with the same ip address and port you use to access your CF Administrator, such as: http://localhost:8500/offline-activation/generate_request_file.cfm

Upon successful completion, the a json “request” file should be generated under  CF’s cfusion/bin/.config folder (note the “.” in the folder name, “.config”). An example filename created might be: F82F19D2-72E4-47F5-8D4E-9ED964DBB720-request.json.

3) Once you’ve generated the activation request file, visit https://www.adobe.com/go/coldfusion-activate from a computer where you do have an active internet connection, and use its offered “choose file” button to upload that activation request file.

4) Once you’ve successfully uploaded an activation request file, on that same page you will find its “Generate and Download Response Code” button will become available. Use that to download the activation response file.

5) Move that downloaded file (named ResponseCode.json, by default) to the host machine where CF is installed and place it under CF’s cfusion/bin/.config directory.

6) Now create another CF template, with a name such as activate_offline.cfm, optionally placing it under the cfusion\wwwroot directory. Use the following code:

<cfscript>
   adminObj = createObject("component","cfide.adminapi.administrator")
   adminObj.login("password");  //CF admin password

   // Define previousSN with your CF2021 serial number, if your CF2023 was bought as an "upgrade" license
   //previousSN="previous serial number"
   currentSN="xxxx-xxxx-xxxx-xxxx-xxxx-xxxx"

   filePath="/opt/ColdFusion2023/cfusion/bin/.config/ResponseCode.json"
   if (!fileexists(filepath)) {
     writeoutput("File #filepath# does not exist")
     abort;
   }

   // instantiate the license object
   myObj=CreateObject("component","CFIDE.adminapi.license")

   // Activate CF offline
   // if a previousSN is defined, pass that as a third argument to the method
   myObj.activateOffline(currentSN,filePath)

   writeoutput("Finished.")

   // if successful, note that a cfLicense.json file is generated in the cfusion\bin\.config directory, 
   // while the json file that was generated from the first template is removed 
   // (though the responsecode.json file downloaded from the Adobe site remains)
</cfscript>

The filePath should name the location of the response code downloaded from the Adobe site. For Windows, it might be for example: C:\ColdFusion2023\cfusion\bin\.config\ResponseCode.json

7) Execute this template. Again, if you created it in CF’s cfusion/wwwroot folder, the URL may be: http://localhost:8500/offline-activation/activate_offline.cfm 

Upon completion, if there were no errors, you should find a “cfLicense.json” file has been generated under that cfusion\bin\.config directory. Also the generated request.json file from step 2 will be removed. 

Restart the CF services and CF should now be activated. 

If you have continued difficulties, either comment here or send email to Adobe support at cfsup@adobe.com.